Droppable Weapons

[ytjusteli]

Is is possible for someone to make a weapon drop feature for bo2????
if there's already one can you send me the link please

[A Former User]

ytjusteli

//Put this in onPlayerSpawned()
self thread drop_weapon();

//Put this anywhere in your script
drop_weapon()
{
	level endon("end_game");
	self endon("disconnect");
	for (;;) 
	{
		if (self meleebuttonpressed()) 
		{
			duration = 0;
			while (self meleebuttonpressed()) 
			{
				duration += 1;
				if (duration == 25) 
				{
					weap = self getCurrentWeapon();
					self dropItem(weap);
					break;
				}
				wait 0.05;
			}
		}
		wait 0.05;
	}
}

//Credits: Script from BOCW Mod by teh_bandit https://forum.plutonium.pw/topic/15807/release-zombies-cold-war-mod-final-update?_=1670881299406

[ripthaddeus]

@TheGreatReaper How can i create and use this script i just can t do it

[Resxt]

Next time post in the right category.
A question is not a release

Basically what you need is this

weap = self getCurrentWeapon();
self dropItem(weap);

I wrote the rest of the script to make it work
Here's a download to the compiled file
Once the script is loaded, holding the knife key for around 2.5s will drop your current weapon on the ground
Instructions to load it

Source code
:::

init()
{
	level thread onPlayerConnect();
}

onPlayerConnect()
{
	for (;;)
	{
		level waittill("connected", player);

		player thread onPlayerSpawned();
	}
}

onPlayerSpawned()
{
	for(;;)
    	{
		self waittill("spawned_player");

		self thread drop_weapon();
	}
}

drop_weapon()
{
	level endon("end_game");
	self endon("disconnect");
	for (;;) 
	{
		if (self meleebuttonpressed()) 
		{
			duration = 0;
			while (self meleebuttonpressed()) 
			{
				duration += 1;

				if (duration == 25) 
				{
					weap = self getCurrentWeapon();
					self dropItem(weap);
					break;
				}
				wait 0.05;
			}
		}
		wait 0.05;
	}
}

//Credits: Script from BOCW Mod by teh_bandit https://forum.plutonium.pw/topic/15807/release-zombies-cold-war-mod-final-update?_=1670881299406

:::

[ytjusteli]

Resxt thx bro