I Need Help with Mod that gives you Paralyzer on first box hit - Buried

[SR2012]

I'm trying to do a challenge & it would save me a whole heap of time to have the paralyzer as a guaranteed first box hit. Someone pls help. i know you can do something with a .gsc file but i have no idea how.

[codywp92]

Do you need it to be from the box or would simply giving it to yourself work?

[codywp92]

try this, save this in a file with the .gsc extension and place it in AppData\Local\Plutonium\storage\t6\scripts\zm

#include maps\mp\zombies\_zm_magicbox;
#include common_scripts\utility;

main()
{
    replaceFunc(maps\mp\zombies\_zm_magicbox::treasure_chest_chooseweightedrandomweapon,::new_treasure_chest_chooseweightedrandomweapon);
}

init()
{
    level thread onplayerconnect();
}

onplayerconnect()
{
    for(;;)
    {
        level waittill("connected", player);
        player thread onplayerspawned();
    }
}

onplayerspawned()
{
    self endon("disconnect");
    for(;;)
    {
        self waittill("spawned_player");
    }
}

new_treasure_chest_chooseweightedrandomweapon( player )
{
    keys = array_randomize( getarraykeys( level.zombie_weapons ) );

    if ( isdefined( level.customrandomweaponweights ) )
        keys = player [[ level.customrandomweaponweights ]]( keys );
    
    pap_triggers = getentarray( "specialty_weapupgrade", "script_noteworthy" );

    for ( i = 0; i < keys.size; i++ )
    {
	if (level.chest_accessed == 0 && level.script == "zm_buried")
	{
	    if ( treasure_chest_canplayerreceiveweapon( player, "slowgun_zm", pap_triggers ) )
		return "slowgun_zm";
	}
	if ( treasure_chest_canplayerreceiveweapon( player, keys[i], pap_triggers ) )
	    return keys[i];
    }
    return keys[0];
}

[SR2012]

thanks heaps codywp92 It worked!