Mod that gives you ray gun mk2 and monkeys/emps on first box

[codywp92]

xenocrafter are you looking to get both rayguns at start of game or do you want to switch the mark2 to the regular raygun?

[xenocrafter]

codywp92 i want a script for the normal ray gun as well so i can practice both guns and practice strats on bus depot

[codywp92]

xenocrafter ok i made the script start you with both rayguns.

#include maps\mp\zombies\_zm_utility;

init()
{
    level thread onplayerconnect();
}

onplayerconnect()
{
    for(;;)
    {
        level waittill("connected", player);
        player thread onplayerspawned();
    }
}

onplayerspawned()
{
    self endon("disconnect");
    for(;;)
    {
        self waittill("spawned_player");
	self takeWeapon("m1911_zm");
	self thread player_give_raygun();
	self thread player_give_raygun_mark2();
	self thread player_give_cymbal_monkey();
	//self thread player_give_emp();
    }
}

player_give_raygun()
{
    self giveweapon( "ray_gun_zm" );
    self SwitchToWeapon("ray_gun_zm");
}

player_give_raygun_mark2()
{
    self giveweapon( "raygun_mark2_zm" );
}

player_give_cymbal_monkey()
{
    self giveweapon( "cymbal_monkey_zm" );
    self set_player_tactical_grenade( "cymbal_monkey_zm" );
    self thread maps\mp\zombies\_zm_weap_cymbal_monkey::player_handle_cymbal_monkey();
}

player_give_emp()
{
    self giveweapon( "emp_grenade_zm" );
    self set_player_tactical_grenade( "emp_grenade_zm" );
}

[xenocrafter]

codywp92 ty brother

[A Former User]

codywp92 bro can u plz make the one that starts the game on round 10 to practice first rooms nobody will do it i tried it and i cant get accurate spawns

[codywp92]

@dfgkbjdfgkhjks what exactly are you looking for? are you just wanting to start on round 10?

[codywp92]

@dfgkbjdfgkhjks

init()
{
    level thread onplayerconnect();
}

onplayerconnect()
{
    for(;;)
    {
        level waittill("connected", player);
        player thread onplayerspawned();
    }
}

onplayerspawned()
{
    self endon("disconnect");
    for(;;)
    {
        self waittill("spawned_player");
	level.round_number=10;
    }
}

[A Former User]

codywp92 when i try that script it seems the zombies are just walkers, the speed isn't as it would be on round 10 and when i set it to round 50 they're still walkers. also, the spawns seem to be very much lower than regular round 50.

[codywp92]

@dfgkbjdfgkhjks
Try this

init()
{
    level thread onplayerconnect();
    level thread setround();
}

onplayerconnect()
{
    for(;;)
    {
        level waittill("connected", player);
        player thread onplayerspawned();
    }
}

onplayerspawned()
{
    self endon("disconnect");
    for(;;)
    {
        self waittill("spawned_player");
    }
}

setround()
{
    round = 10;
    level.first_round = round;
    level.start_round = round;
    level.round_number = round;
	
    if ( level.gamedifficulty == 0 )
        level.zombie_move_speed = level.round_number * level.zombie_vars["zombie_move_speed_multiplier_easy"];
    else
        level.zombie_move_speed = level.round_number * level.zombie_vars["zombie_move_speed_multiplier"];

    if ( level.round_number == 1 )
        level.zombie_move_speed = 1;
    else
    {
        for ( i = 1; i <= level.round_number; i++ )
        {
            timer = level.zombie_vars["zombie_spawn_delay"];

            if ( timer > 0.08 )
            {
                level.zombie_vars["zombie_spawn_delay"] = timer * 0.95;
                continue;
            }

            if ( timer < 0.08 )
                level.zombie_vars["zombie_spawn_delay"] = 0.08;
        }
    }
}

[SR2012]

codywp92 im trying to get the paralyzer from the box every time on buried. But i dont have the the scripts file after storage/t6. I do have one that says raw/scripts/zm though, but it only has 1 file in there thats called 'ranked.gsc'. Can you help me by making a script for that & helping me with where to put it?