drop points

Sprully

is there a script that allows players to drop points

Kalitos

Sprully You mean drop the points to the ground, or give points to another player.

Sprully

Kalitos either is fine just a way to share my own points with others

Kalitos

#include common_scripts\utility;
#include maps\mp\zombies\_zm;
#include maps\mp\zombies\_zm_weapons;
#include maps\mp\zombies\_zm_utility;
#include maps\mp\gametypes_zm\_hud_util;
#include maps\mp\gametypes_zm\_hud_message;
#include maps\mp\_utility;
#include common_scripts\utility;

init()
{	   		
    level thread onsayPlayer();	
}

onsayPlayer()
{
    level endon("game_ended");    
    for(;;)
    {
        level waittill( "say", message, player );
        sayText = strtok(tolower(message), " ");        
        if(sayText[0]==".send" || sayText[0]=="/.send") //GivePoints
        {
            if(sayText.size>1)
            {
                for( i = 0; i < level.players.size; i++ )
                {
                    if( isSubStr( tolower( getPlayerName( level.players[ i ] )), tolower(sayText[ 1 ] ) ))
                    {
                        value = int( sayText[ ( sayText.size - 1 ) ] );
                        if( value < 0 )
                            value = ( value * -1 );
                        player give_points( level.players[ i ], int( value ));
                    }                    
                }
            }else
            {
                player iPrintLn("Use ^2.send ^1name ^2amount");
            }
        }       
    }
}

give_points( player, var )
{
	if( !isDefined( self.giving_points ) )
	{
		self.giving_points = true;
		if ( player.score == 1000000 )
			self iPrintLn( getPlayerName( player ) + " already has ^51000000 ^7points" );
		else if( self.score >= var )
		{
			self maps/mp/zombies/_zm_score::minus_to_player_score( var, 1 );
			self iPrintLn( "^1Gave ^7" + getPlayerName( player ) + " ^1" + var + " ^7points" );
			player maps/mp/zombies/_zm_score::add_to_player_score( var, 1 );
			player iPrintLn( "^2" + getPlayerName( self ) + " ^7gave you ^2" + var + " ^7points" );
		}
		else
			self iPrintLn( "^1You don't have enough points for that" );
		wait 1;
		self.giving_points = undefined;
	}
}

getPlayerName( player )
{
    playerName = getSubStr( player.name, 0, player.name.size );
    for( i = 0; i < playerName.size; i++ )
    {
		if( playerName[ i ] == "]" )
			break;
    }
    if( playerName.size != i )
		playerName = getSubStr( playerName, i + 1, playerName.size );
		
    return playerName;
}

Sprully

thank you for sharing im testing now

Danielow

Which comands i need to send money to my friend??

ArleneExcalibur

Kalitos Do we have to type the entire name?

Kalitos

@Arlene-Excalibur No, but you must write at least the first 4 or 5 letters. Sometimes you may have to write the whole name

Kalitos

Danielow In the example, the command would be ".send name points"

Plutonium

drop points