[Release] [GSC] Zombies Custom Powerup | Unlimited Ammo

[Ox_]

Fry said in [GSC] Zombies Custom Powerup | Unlimited Ammo:

OP is your code on the main post the latest changes of the GSC? I have been thinking about merging this to RG server along with unlimited perks etc. I just wanted to make sure before I push it live.

Yes it was, and will always be. Also just pushed a big update.

banni said in [GSC] Zombies Custom Powerup | Unlimited Ammo:

Tried improving the code, added ambient sound when powerup is active, and iprintin message about powerup being picked up and being ended. I also tried drawing a hud powerup icon but it doesn't work.
I also removed zombie blood code because it wasn't working.

#include maps\mp\_utility;
#include common_scripts\utility;
#include maps\mp\gametypes_zm\_hud_util;
#include maps\mp\gametypes_zm\_hud_message;

//important include
#include maps\mp\zombies\_zm_powerups;

init()
{
	level thread onPlayerConnect();
    precacheshader( "zom_icon_minigun" ); // tried precaching death machine icon for hud, didn't work for some reason
	include_zombie_powerup("unlimited_ammo");
	add_zombie_powerup("unlimited_ammo", "T6_WPN_AR_GALIL_WORLD", &"ZOMBIE_POWERUP_UNLIMITED_AMMO", ::func_should_always_drop, 0, 0, 0);
	powerup_set_can_pick_up_in_last_stand("unlimited_ammo", 1);
}

onPlayerConnect()
{
	for(;;)
	{
		level waittill("connected", player);
		player thread onPlayerSpawned();
	}
}

onPlayerSpawned()
{
	self endon("disconnect");
	level endon("game_ended");
	for(;;)
	{
		self waittill("spawned_player");
			//only run this when the host spawns in for the very first time
			if(!isDefined(level.unlimited_ammo_first_spawn))
			{
				wait 2;
				level._zombiemode_powerup_grab = ::custom_powerup_grab;
				level.unlimited_ammo_first_spawn = "fortnite!fortnite!!";
			}
			
	}
}

//fires when we grab any custom powerup
custom_powerup_grab(s_powerup, e_player)
{
	if (s_powerup.powerup_name == "unlimited_ammo")
		level thread unlimited_ammo_powerup(s_powerup, e_player);
	    
}

unlimited_ammo_powerup(m_powerup, e_player)
{
	foreach(player in level.players)
	{
		//if powerup is already on, turn it off
		player notify("end_unlimited_ammo");
        //decided to use stinger from when you get ray gun from box
		player playsound("mus_raygun_stinger");
		player thread turn_on_unlimited_ammo();
		player thread notify_unlimited_ammo_end();
		player thread sfx_inf_ammo();
                player thread ammo_hud_create();
		player iprintln("^2Bottomless Clip!");  
		wait 30;
		player iprintln("^1Bottomless Clip has ended!");
		player playsound("zmb_insta_kill_loop_off");

	}
	
}

sfx_inf_ammo()
{
    level endon("game_ended");
	self endon("disconnect");
	self endon("end_unlimited_ammo");
	inf_ammo_ent = spawn( "script_origin", ( 0, 0, 0 ) ); 
	inf_ammo_ent playloopsound( "zmb_insta_kill_loop" );
	wait 30;
	inf_ammo_ent stoploopsound();
	inf_ammo_ent destroy();

}
//my attempt at making a hud icon for it, as expected, it didn't work
ammo_hud_create()
{
	self.ammo_icon = newclienthudelem( self );
	self.ammo_icon.horzalign = "center";
	self.ammo_icon.vertalign = "middle";
	self.ammo_icon.x = -16;
	self.ammo_icon.y = 16;
	self.ammo_icon.alpha = 0;
	width = 64;
	height = 64;
	self.ammo_icon setshader( "zom_icon_minigun", width, height );	
        wait 30;
        self.ammo_icon destroy();
}

turn_on_unlimited_ammo()
{
	level endon("game_ended");
	self endon("disconnect");
	self endon("end_unlimited_ammo");	

    self setWeaponAmmoClip(self GetCurrentWeapon(), 150);
	
	for(;;)
	{
	    self waittill ("weapon_fired");
		//simply set the current mag to be full on a loop
		self setWeaponAmmoClip(self GetCurrentWeapon(), 150);
		wait .02;
	}
}

notify_unlimited_ammo_end()
{
	level endon("game_ended");
	self endon("disconnect");
	self endon("end_unlimited_ammo");
	//changed duration to 30 because why not 
	wait 30;
	self notify("end_unlimited_ammo");

}

The zombie blood was working as intended. Did you read the comments about it?
It wasn't supposed to add the zombie blood powerup to all maps, just make it functional in Origins. Your current code overwrites the custom powerup pickup function and it doesn't include zombie blood so the powerup is broken in your code.
My latest version right now uses a better way of not breaking zombie blood though, check the edit in OP.

And not bad with the raygun sound. I would probably use it if I wasn't too used to knowing that sound means someone got it from the random box. Do you have a list of sounds? All I have nowadays is what I find from Google, and wasn't able to find anything good.

Also I decided not to add that ambient sound to my latest version. I tried your stuff and literally could not hear a thing. So I don't see the point. Maybe if there was some good sound, but well, don't know of one.

And about your hud, the biggest problem with it is that you set it to be fully transparent alpha = 0. So yeah, can't really see it haha.
See my latest version in OP though, I added a hud.

And you can't wait inside the unlimited_ammo_powerup() function. Right now in your code the first player gets the powerup and then 30seconds later the second player gets the powerup, etc.

Also I decided not to take the waittill("weapon_fired") approach, since it's no good if you swap to a weapon that would have to reloaded, or if you're out of ammo. And also, setting the current clip to be full every .05sec is literally nothing in gsc. So I don't see any point bothering to implement proper logic for handling it with waittills.

And yeah, I guess 30sec duration is good. First I thought it's a bit too much, but meh, whatever, I'll make it be that.

Btw, "Bottomless Clip", love the name haha.
I added that in, thanks.

[Ox_]

JezuzLizard latest version is up now.
I'll check out your version tomorrow probably and see about adding it to the OP as well.

[Knight]

Ox_ I literally was just gonna post my source of my new power-up I cobbled together and I noticed you updated your source guess I'll have to go through it. but ill still post an images of the power-up next to yours.

Pictures (sorry for the gigantic pics before lol)
https://imgur.com/gallery/BH4k3C7

I think you get the idea, it's the Pack-A-Punch power up!
It paps your gun! Oh and I used the teddy bear model because I couldn't find a pap.

[Ox_]

Knight said in [GSC] Zombies Custom Powerup | Unlimited Ammo:

Ox_ I literally was just gonna post my source of my new power-up I cobbled together and I noticed you updated your source guess I'll have to go through it. but ill still post an images of the power-up next to yours.

Pictures (sorry for the gigantic pics before lol)
https://imgur.com/gallery/BH4k3C7

I think you get the idea, it's the Pack-A-Punch power up!
It paps your gun! Oh and I used the teddy bear model because I couldn't find a pap.

Good stuff. Would like to see your implementation of the countdown, always interesting to see what sort of approaches other people have taken.
About the powerup itself, sounds quite overpowered to me haha. Would need some balancing done to it for sure.

If you're up for a challenge, try to balance the powerup.
What I'd look into myself, is changing its spawning chance based on in what stage of the game players are.
E.g. really rare to spawn in unless pap is legitmately accessible as well. Also based on how much money the player has.
And if players are really late game, could spawn it in quite commonly just for fun. In such a case I wouldn't use the normal way of spawning them in though. You wouldn't want to consume the limit of powerups per round and push chances of max ammo off powerup array.
I guess same could be said about adding any custom powerup, it always makes max ammo more rare. I didn't see this is a problem with unlimited ammo though, since it should be quite good at high rounds and you also fill up your current clip at least.

[GroverFox]

Really like this and hope someday to learn how to do it.

[Ox_]

GroverFox said in [GSC] Zombies Custom Powerup | Unlimited Ammo:

Really like this and hope someday to learn how to do it.

If you're just looking to use it, there's a download the precompiled .gsc you can use.
How you use this .gsc depends a bit. If you're looking to use it on a Plutionum server, they have a tutorial stickied in here.
If not on a Plutonium server, you can Google for a tutorial on how to inject it to Steam/Redacted.

[GroverFox]

No, I'm taking about the coding part

[Ox_]

GroverFox said in [GSC] Zombies Custom Powerup | Unlimited Ammo:

No, I'm taking about the coding part

I see.
Well good luck with with the learning

[Optimus X]

This post is deleted!

[Ox_]

@colorz808 said in [Release] [GSC] Zombies Custom Powerup | Unlimited Ammo:

Ox_ Are you going to make more custom power ups? I would like to see a perk bottle powerup that gives a perk to all players that leads to gaining all 7 perks on any map or perhaps a pack o punch powerup to upgrade your gun for maps like bus depo or farm that don't have a pack o punch machine. I've used your Unlimited Ammo Powerup and I enjoy it alot when I host my server. Great Work

Guess I could make more. Just seriously lost motivation when I made the nice shader at the bottom of the screen for the powerup timer and all, just to notice it doesn't work for all maps.

Ideas are appreciated though, the more complex, the more interesting it is (but that could also result in cba, haha)
And I don't think I quite understand what your first idea is. Just normal perk bottle powerup, but it also increases the perk cap? Or?
And for pack-a-punch, seems like Knight made it already, here's his post. Maybe he could share it.

[Optimus X]

Thanks for the info on Knight already making the pap powerup i'll see if he can share but for the perk powerup I was thinking can give perks like flopper etc that are not originally in the map like town or farm. Everytime they grab the perk bottle it gives everyone one random free perk but it's random between 8 perks like the wunderfizz machine on origins

[JezuzLizard]

@colorz808 This isn't possible yet not without mod tools. The actual perks aren't on the fast file the map loads so if you do try to give say "specialty_flakjacket" which is flopper the game will crash.

Modding is currently limited to whatever is actually on the fast file, if its not on the fast file already and its not a script its not possible. It is possible to bring over scripts from other maps and use their functions in any map but with varying results.

[Optimus X]

Thanks for the information. Hopefully in the future it's possible.

[Knight]

@colorz808 and Ox_ I'll gladly share my code, to be totally honest it wan't that hard to make the pack a punch perk I used code from Rezhified credit to him for the pap code here is the code:

#include maps\mp\_utility;
#include common_scripts\utility;
#include maps\mp\gametypes_zm\_hud_util;
#include maps\mp\gametypes_zm\_hud_message;

//important include
#include maps\mp\zombies\_zm_powerups;
#include maps\mp\zombies\_zm_weapons;

//making the code seperate for the Pack-A-Punch Power-Up to make it less confusing.
//but they could be merged as I've done before.

//Credits
// to _Ox for the original code, also thanks for the notes it was really helpful.
// and to Rezhified for the pack-a-punch code.

init()
{
	
	level thread onPlayerConnect();
	 
	include_zombie_powerup("upgrade_weapon"); 
	
	add_zombie_powerup("upgrade_weapon", "zombie_teddybear", &"ZOMBIE_POWERUP_UPGRADE_WEAPON", ::func_should_always_drop, 0, 0, 0);
	powerup_set_can_pick_up_in_last_stand("upgrade_weapon", 1);

}

/*func_should_drop_past_level()
{
	if ( level.round_number < 5 )
	{
		return 0;
	}
	return 1; 
}*/

onplayerconnect()
{
    for(;;)
    {
        level waittill("connected", player);
        player thread onPlayerSpawned();
    }
}

onplayerspawned()
{
    self endon("disconnect");
	level endon("game_ended");
    for(;;)
    {
        self waittill("spawned_player");
        if(self isHost() && !isDefined(level.custom_powerup_first_spawn))
        {
        	wait 2;
        	//store the original custom powerup grab function, 
        	//if one exists (Origins, Buried, Grief & Turned)
        	//note that this is not intended for Grief or Turned
        	//I have no idea what will happen, probably pretty broken
        	if(isDefined(level._zombiemode_powerup_grab))
        		level.original_zombiemode_powerup_grab = level._zombiemode_powerup_grab;
        		
        	//delayed defining of the custom function so we're sure to
        	//override the function Origins and Buried defines for this
        	level._zombiemode_powerup_grab = ::custom_powerup_grab;
        	
        	//message for the host to indicate that it should be all good
        	wait 2;
		self iprintlnbold("^7Custom Powerup Loaded!");
        	
        	//gives host the ability to test the powerup at the start of the game
        	//can be used to make sure it's actually working and all good
        	//remove the line directly below to disable
        	self thread test_the_powerup();
        	
        	//whatever so this variable isn't undefined anymore
        	level.custom_powerup_first_spawn = "fortnite!fortnite!!";
        }
    }
	
}

test_the_powerup()
{
	self endon("death");
	self endon("disconnected");
	self endon("testing_chance_ended");
	level endon("game_ended");
	wait 3;
	self iprintlnbold("^7Press ^1[{+smoke}] ^7to test, you have ^15 seconds^7.");
	self thread testing_duration_timeout();
	for(;;)
	{
		if(self secondaryoffhandbuttonpressed())
		{
			level specific_powerup_drop("upgrade_weapon", self.origin + VectorScale(AnglesToForward(self.angles), 70));
			return;
		}
		wait .05;
	}
}

testing_duration_timeout()
{
	self endon("death");
	self endon("disconnected");
	wait 5;
	self notify("testing_chance_ended");
}

//fires when we grab any custom powerup
custom_powerup_grab(s_powerup, e_player)
{
	if (s_powerup.powerup_name == "upgrade_weapon")
		level thread upgrade_weapon_powerup();
	
	//pass args onto the original custom powerup grab function
	else if (isDefined(level.original_zombiemode_powerup_grab))
		level thread [[level.original_zombiemode_powerup_grab]](s_powerup, e_player);
}


upgrade_weapon_powerup()
{
	foreach(player in level.players)
	{
		//if powerup is already on, turn it off
		//player notify("end_unlimited_ammo");
		//small cha ching sound for each player when someone picks up the powerup
		//cba'd to come up with anything better and don't have a list of sounds, 
		//change to w/e if you want.
		
		player playsound("zmb_cha_ching");
		player thread upgrade_players_weapon();
		
		//player thread turn_on_unlimited_ammo();
		//player thread unlimited_ammo_on_hud();
		//player thread notify_unlimited_ammo_end();
	}
}

//Rezhified pack-a-punch code. Rezhified.#3039 on discord. [Link To His Source](https://cabconmodding.com/threads/black-ops-2-gsc-managed-code-list.158/post-43365)
upgrade_players_weapon() 
{
	level endon("game_ended");
	self endon("disonnect");
	
    baseweapon = get_base_name(self getcurrentweapon());
    weapon = get_upgrade(baseweapon);
    if(IsDefined(weapon))
    {
        self takeweapon(baseweapon);
        self giveweapon(weapon, 0, self get_pack_a_punch_weapon_options(weapon));
        self switchtoweapon(weapon);
        self givemaxammo(weapon);
    }
}

get_upgrade(weapon)
{
    if(IsDefined(level.zombie_weapons[weapon].upgrade_name) && IsDefined(level.zombie_weapons[weapon]))
        return get_upgrade_weapon(weapon, 0 );
    else
        return get_upgrade_weapon(weapon, 1 );
}


/*Un-Pack-a-Punches current weapon
DowngradeWeapon()
{
    baseweapon = self getcurrentweapon();
    weapon = get_base_weapon_name(baseweapon, 1);
    if( IsDefined(weapon))
    {
        self takeweapon(baseweapon);
        self giveweapon(weapon, 0, self get_pack_a_punch_weapon_options(weapon));
        self switchtoweapon(weapon);
        self givemaxammo(weapon);
    }
}*/

I was trying to figure out how to put something in to stop the perk from being spawned in at low rounds but couldn't figure it out. Maybe someone could figure it out. Thanks again Ox_ for making your code public, your an amazing coder. Would love to see this being used in servers especially if a round limiter is implemented.

Well looks like I left the func_should_drop_past_level() function in by mistake it should work now, but will always drop sorry about that.

[Optimus X]

Knight Thank You, Knight. I will use this when I host my server. Be perfect for farm and bus depot. Wish I knew how to get those map working correctly on my server. Any help you can give would be greatly appreciated

[JezuzLizard]

Knight I believe you'll have to modify _zm_powerups.gsc itself to manually set conditions for drops. Its possible since fire sale is an example of one such powerup. I have a _zm_powerups.gsc that compiles but will have errors with custom powerups you'll have to fix it if you want it to work with your powerup but it shouldn't be that difficult.

https://github.com/JezuzLizard/Recompilable-gscs-for-BO2-zombies/tree/master/patch_zm
If you do manage to figure out why the function custom_powerup_grab doesn't run make a pull request, otherwise I'll probably fix it later today after I finish working on _zm.gsc.

Oh yeah I guess I should also explain how you make use of recompileable .gscs. Just compile it as _zm_powerups.gsc and place it maps/mp/zombies. The game will run this version of _zm_powerups.gsc instead of the base version allowing for total customization of the base powerups.

[ElotitoGameplay]

This post is deleted!

[MisterX2003]

This post is deleted!

[AdrX003]

Ox_ I play grief and turned...

[Vin Soren]

intento agregar caulquiera de los anteriores codigos a un servidor propio y no funcionan, los power ups aparecen pero no hacen nada, y en partidas locales si funcionan bien, alguien me puede ayudar??