How do I make Paralyzer work?

Misumi'El

On most of the servers I enter, the Paralyzer on the Buried map does not work properly. You cannot use it to float, fly or levitate.

I've seen that it's a problem with Plutonium itself, but I've seen it work on some servers. So how do I make it work?

Cahz

Misumi'El Here's a quick GSC hot-fix for the flying. The paralyzer slow-mo is still broken, and the flying really only works for the player with the paralzyer. But still works well enough to be used.

Add these functions into your GSC file

paralzyer_flying()
{
    self endon("disconnect");
    level endon("end_game");
    
    self.flypower = 100;
    for(;;)
    {
        if(self.flypower < 100 && !isDefined(self.flying))
            self.flypower++;
        if(!isDefined(self.flying) && !self isOnGround())
            self.flying = true;
        else if(self isOnGround())
            self.flying = undefined;
        wait .05;
    }
}

paralzyer_check()
{
    self endon("disconnect");
    level endon("end_game");
    
    for(;;)
    {
        if(self getCurrentWeapon() == "slowgun_zm" || self getCurrentWeapon() == "slowgun_upgraded_zm")
        {
            if(self attackbuttonpressed())
            {
                foreach(player in level.players)
                {
                    if(distance(self.origin, player.origin) < 120 && isDefined(player.flying) && player.flypower > 0)
                    {
                        player.flypower--;
                        if(player getvelocity() [2] < 300)
                            player setvelocity(player getvelocity() + (0,0,41));
                    }
                }
            }
        }
        wait .05;
    }
}

Add the 2 function threads into your OnPlayerConnect function (like below)

onPlayerConnect()
{
    for(;;)
    {
        level waittill("connected", player);
        player thread paralzyer_flying(); //Add this line
	player thread paralzyer_check(); //And this line into your GSC
    }
}

Misumi'El

This post is deleted!

A7Med_5

where put this
paralzyer_flying()
{
self endon("disconnect");
level endon("end_game");

self.flypower = 100;
for(;;)
{
    if(self.flypower < 100 && !isDefined(self.flying))
        self.flypower++;
    if(!isDefined(self.flying) && !self isOnGround())
        self.flying = true;
    else if(self isOnGround())
        self.flying = undefined;
    wait .05;
}

}

paralzyer_check()
{
self endon("disconnect");
level endon("end_game");

for(;;)
{
    if(self getCurrentWeapon() == "slowgun_zm" || self getCurrentWeapon() == "slowgun_upgraded_zm")
    {
        if(self attackbuttonpressed())
        {
            foreach(player in level.players)
            {
                if(distance(self.origin, player.origin) < 120 && isDefined(player.flying) && player.flypower > 0)
                {
                    player.flypower--;
                    if(player getvelocity() [2] < 300)
                        player setvelocity(player getvelocity() + (0,0,41));
                }
            }
        }
    }
    wait .05;
}

}

Cahz

A7Med_5 You need to load a custom GSC file that you create. Follow this guide to learn more about custom GSC scripts and how to load them for custom games with friends or a dedicated server.

AmadeusHusky

hope im not necroposting, but i can't get the script to work.

**** 2 script error(s):
**** Unresolved external :  "paralyzer_flying" with 0 parameters in "maps/mp/_imcsx_gsc_studio.gsc" at line 1 ****
**** Unresolved external :  "paralyzer_check" with 0 parameters in "maps/mp/_imcsx_gsc_studio.gsc" at line 1 ****

daniksnaknak

why cant i fly with paralyser? even though im in a solo game