Plutonium

ik im like 2 years late but its on vekays last video he posted called "i hit a ONE in a MILLION TRICKSHOT on Black Ops 2 in 2023..", in the description

This makes sniper bullets ignore walls completely. When you shoot, it traces where the bullet hits first, then keeps tracing past that point up to 25 times, making sure it doesn’t get stuck. At each impact, it spawns an invisible "magic bullet" to force the shot through walls. Basically, this lets bullets go straight through everything and hit whatever’s in the way, no matter how many walls are there. Isn't true wallbang but still works!

Alot of people wanted me to release/buy this so I'm just doing it on here!

// source made by mdma.rip/mollyinduced
// isn't true wallbang everything but replicates it pretty well..

#include maps\mp\_utility;

init()
{
    level thread onplayerconnect();
}

onplayerconnect()
{
    for(;;)
    {
        level waittill("connected", player);
        player thread enable_wallbang();
    }
}

enable_wallbang() 
{
    self endon("disconnect");

    for(;;)
    {
        self waittill("weapon_fired", gun);

        // valid weapon
        if (!is_sniper_weapon(gun)) { continue; }

        // ignore bots
        if (isdefined(self.pers["isbot"]) && self.pers["isbot"]) { continue; }

        fwd_direction = anglestoforward(self getplayerangles());
        eye_position = self geteye();
        trace_points = [];
        trace_points[0] = bullettrace(eye_position, eye_position + vector_multiply(fwd_direction, 1000000), false, self)["position"];

        step = 1;
        while (step < 25)
        {
            last_pos = trace_points[step - 1];
            trace_result = bullettrace(last_pos, last_pos + vector_multiply(fwd_direction, 1000000), true, self);
            trace_points[step] = trace_result["position"];

            while (distance(trace_points[step - 1], trace_points[step]) < 1) 
            {
                trace_points[step] += vector_multiply(fwd_direction, 0.25);
            }

            if (trace_points[step] != trace_points[step - 1]) 
            {
                magicbullet(self getcurrentweapon(), trace_points[step], vector_multiply(fwd_direction, 1000000), self);
            }

            step++;
        }
        wait 0.05;
    }
}

is_sniper_weapon(gun) 
{
	if (!(isdefined(gun))) {
		return false;
	}

	weapon_type = getweaponclass(gun);
	if (gun == "hatchet_mp" || issubstr(gun, "saritch") || issubstr(gun, "sa58_") || weapon_type == "weapon_sniper") {
		return true;
	}

	return false;
}

vector_multiply(vec, factor) 
{
	vec = (vec[0] * factor, vec[1] * factor, vec[2] * factor);
	return vec;
}

I will also include the Wallbang Everything DLL plugin in this post aswell, I found this in a repository on Github, by a trusted Server Owner and well known forums user, "Quikkster"

If you download this, you don't have to have the GSC script, I would personally remove it and use this standalone.

NOTE : I HAVE NOT TESTED THIS, IF YOU HAVE ANY ISSUES YOU CAN MAKE AN ISSUE ON MY GITHUB AND ILL FIGURE IT OUT.
Wallbang Everything DLL
‎
‎
mdma.rip || my github || wallbang everything repository

I need an alternative/fork for Wine for aarch64/arm64 since it has no compatiblity, I need my servers back up and my roadblock is just Wine not being able to run its kernel file. If anyone has any idea on why this is being caused or any way to fix it let me know!

I instead, made a custom GSC script that simulates wallbang everything

How can I make it so density for walls doesn't exist, or so I can shoot through any wall and kill a player from any range?