[Release] [Zombies] Black Ops 1 aim assist

[dontknowletspl]

Chooch What is that supposed to mean?

[Bongo777]

Nice code, but isn't Controller Support/Aim Assist already built in? Does this code make the aim assist more natural or what exactly does it do?

[dontknowletspl]

Bongo777 I have no idea what kind of aim assist bo1 has. If there is already good aim assist like on console then you do not need this script.

[IKennyAgain]

Bongo777 there is aim assist but it has no snap on zombies body like in console version

[dontknowletspl]

IKennyAgain This script has it.

[BalticDude]

It has a weird jitteryness to it when zombies move after you press it almost like it's following until you've aimed all the way. Any way you could remove that jitter and just make it zoom to the center immediately when you press the button like it does in the console version?

[dontknowletspl]

@IcedVenom On ps3 bo2 it has it like that but alot smoother which i don't think is possible with gsc but if you want to remove it here is the code.

//Call of Duty Black ops 1 Aim Assist

#include maps\_utility;
#include common_scripts\utility;

init()
{
    if ( GetDvar( #"zombiemode" ) == "1" )
	{
		level thread onPlayerConnect();
	}
}

onPlayerConnect()
{
    level endon( "end_game" );
	for ( ;; )
	{
        if(isDefined(level.player_out_of_playable_area_monitor) && level.player_out_of_playable_area_monitor) //disable death barriers
			level.player_out_of_playable_area_monitor = 0;
        if(isDefined(level.player_too_many_weapons_monitor) && level.player_too_many_weapons_monitor) //disable too many weapons check
			level.player_too_many_weapons_monitor = 0;

		level waittill( "connected", player );
        player thread AimAssist();
		player thread onSpawn();
	}
}

onSpawn()
{
	self endon( "disconnect" );
    self waittill( "spawned_player" );
    wait 5;
    iprintln( "aim assist enabled" );
}

AimAssist()
{
	level endon("end_game");
	self endon("disconnect");
	for(;;)
	{

		if(isDefined( level.zombiemode_using_deadshot_perk ) && level.zombiemode_using_deadshot_perk && self hasperk("specialty_deadshot")) //original perk check
			tag = "j_head";
		else
			tag = "j_spine4";

		view_pos = self GetWeaponMuzzlePoint();
		zombies = get_array_of_closest( view_pos, getaispeciesarray("axis", "all"), undefined, undefined, undefined );		
		range_squared = 500 * 500;
		for ( i = 0; i < zombies.size; i++ )
		{
			if ( !IsDefined( zombies[i] ) || !IsAlive( zombies[i] ) )
			{
				continue;
			}
			enemy_origin = zombies[i].origin;
			test_range_squared = DistanceSquared( view_pos, enemy_origin );
			if ( test_range_squared < range_squared )
			{
				if(zombies[i] player_can_see_me(self))
				{
					if(self adsButtonPressed() && self playerADS() < 0.6 )
					{
						
						self setPlayerAngles(vectorToAngles((zombies[i] getTagOrigin(tag)) - (self getEye())));

						while( self adsButtonPressed() )
						{
							wait .05;
						}
						break;
					}
				}
			}
		}
		wait 0.05;
	}
}

player_can_see_me( player )
{
    playerangles = player getplayerangles();
    playerforwardvec = anglesToForward( playerangles );
    playerunitforwardvec = vectornormalize( playerforwardvec );
    banzaipos = self.origin;
    playerpos = player getorigin();
    playertobanzaivec = banzaipos - playerpos;
    playertobanzaiunitvec = vectornormalize( playertobanzaivec );
    forwarddotbanzai = vectordot( playerunitforwardvec, playertobanzaiunitvec );
    if ( forwarddotbanzai >= 1 )
    {
        anglefromcenter = 0;
    }
    else if ( forwarddotbanzai <= -1 )
    {
        anglefromcenter = 180;
    }
    else
    {
        anglefromcenter = acos( forwarddotbanzai );
    }
    playerfov = getDvarFloat( "cg_fov" );
    banzaivsplayerfovbuffer = getDvarFloat( "g_banzai_player_fov_buffer" );
    if ( banzaivsplayerfovbuffer <= 0 )
    {
        banzaivsplayerfovbuffer = 0.2;
    }
	distance = self check_distance(player);

	playercanseeme = anglefromcenter <= ( ( playerfov * distance ) * ( 1 - banzaivsplayerfovbuffer ) );
	return playercanseeme;
}

check_distance(player)
{
	if(distance(self.origin, player.origin) < 90)
		return .45;
	if(distance(self.origin, player.origin) <= 100)
		return .4;
	if(distance(self.origin, player.origin) <= 150)
		return .3;
	if(distance(self.origin, player.origin) <= 200)
		return .25;
	if(distance(self.origin, player.origin) <= 250)
		return .225;
	if(distance(self.origin, player.origin) <= 300)
		return .2;
	if(distance(self.origin, player.origin) <= 350)
		return .175;
	if(distance(self.origin, player.origin) <= 400)
		return .15;
	return .125;
}

[BalticDude]

@dontknowletsplay Could you also lower the range it locks on to? I'm not sure if it's the same with console but it seems like it jumps really far even when looking at other zombies.

[dontknowletspl]

@IcedVenom This part is the range range_squared = 500 * 500; lower it as you like.

[BalticDude]

@dontknowletsplay Thanks

[dontknowletspl]

Added support for special zombies like dogs.

[XODreams]

GhostRider0125 Hey man i kno this is weird to ask but do i just open a text document on my computer past this in and save it as .GSC then put it in the folder?

[dontknowletspl]

XODreams yes

[GhostRider0125]

XODreams i dont know about coding nor do i do i know about gsc scripts all i know is texture changing

[Miaa_]

Hey, jus twanted to say thanks, this is a very cool thing you did ! Also very cool of you to keep updating it and refining it with feedback, really means a lot to us

[iBest14]

Does it also work for campaign mode?

[dontknowletspl]

iBest14 No its only meant for zombies

[iBest14]

dontknowletspl and can you create one for the campaign mode? or adapt that same one?

[dontknowletspl]

iBest14 Plutonium does not support campaign so im not sure how you would load the script with steam version. I have never made any scripts for campaign.

[menlover33]

This post is deleted!