The completion saves in a dvar on solo, and as a stat in CO-OP. Those are also where it gets checked from. To check if the completion counted, you could create a file, name it sq_completion_check.gsc (make sure you have file name extensions enabled), paste the following snippet of code into it:
init()
{
thread completionCheck( "COTD" );
}
completionCheck( id )
{
common_scripts\utility::flag_wait( "all_players_spawned" );
waittillframeend;
msg = "sq_completion_check " + id + ": " + maps\_zombiemode::is_sidequest_previously_completed( id );
iPrintLn( msg );
printf( msg );
msg = "sq_completion_check " + id + " solo: " + ( isdefined( level.zombie_sidequest_solo_collectible[id] ) && HasCollectible( level.zombie_sidequest_solo_collectible[id] ) );
iPrintLn( msg );
printf( msg );
if ( !isdefined( level.zombie_sidequest_coop_stat[id] ) )
{
return;
}
for ( i = 0; i < level.players.size; i++ )
{
msg = "sq_completion_check " + id + " " + level.zombie_sidequest_coop_stat[id] + " " + level.players[i].playername + ": " + level.players[i] maps\_zombiemode::zombieStatGet( level.zombie_sidequest_coop_stat[id] );
iPrintLn( msg );
printf( msg );
wait 1;
}
}
save the file, press Win+R, paste this path %localappdata%\Plutonium\storage\t5\scripts\sp\zom, place the file into the directory that opened, start a CotD match, then observe the output.
You should see an output similar to this:
sq_completion_check COTD: 1
sq_completion_check COTD solo: 1
sq_completion_check COTD ZOMBIE_COAST_EGG_COOP player_name: 1
The 1st line determines if the Easter Egg of CotD in this match is considered as previously completed. The 2nd line displays the result of what’s checked for the Easter Egg to be considered as previously completed in solo. Similarly, the 3rd line displays the result of what’s checked for the Easter Egg to be considered as previously completed in CO-OP.
You’ll want the number to show as 1 at the end of the 1st line and also at the end of the 2nd line if you’re playing solo and/or at the end of the 3rd line if you’re playing co-op. Otherwise, the completion didn’t save or you didn’t fully complete the Easter Egg. Note that the end of the CotD Easter Egg is when the Wunderwaffe power-up spawns in after knifing the sparking fuse.
